Since you can't quit without saving (right?), I wanted to know if there was a way to back up your saved game.

Yes. The save files are STARA.COM and STARB.COM they are in the GOG directory under Starflight 1/STARFLT/PLAY. To backup you can simply make copies of these.

BONUS ROUND:
Some fans back in the day modified the savegame mechanism of Starflight 2 to work with Starflight 1. I'm not sure who did this originally but I got them from starflt.com.

I zipped the necessary files up and put them here.
Unzip them to <Gog directory>/Starflight 1 and 2/Starflight 1/STARFLT/PLAY

Then modify your conf file at <Gog directory>/Starflight 1 and 2/Starflight 1/dosboxSF1.conf and change the second to last line from "STARFLT.COM" to "call SF1.BAT"

EDIT: I have updated the link to what will hopefully prove a more permanent location.

The instructions have changed to (I'm now using GOG Galaxy and GOG's installer for Starflight has changed).

Unzip them to <Gog directory>/Starflight/Starflight 1/STARFLT/PLAY

Then modify your conf file at <Gog directory>/Starflight/dosboxSF1_single.conf and change the second to last line from "STARFLT.COM" to "call SF1.BAT"

Oddly, there is also a folder titled SAVE under Starflight 1. But it appears to be empty.

This is to do with one of the .bat files, REMEMBER and RESET I believe. The idea is that you edit the .bat files to point to your SAVE folder, then when you run them, you can backup and restore your games. But considering you can do this through a graphical interface, there's not much point in them.

As for backing up, I also recommend copying STARFLT.com and YESNO.com along with STARA and STARB, just in case.

The fan made save system is pretty ingenious. I just made my own before I started playing. Just a batch file (also have to modify the DOSBox config file to run it) which gives you save/restore/delete in nine "save slots" and also the "Reset" option.

Here it is:

[spoiler]

@echo off
:mainmenu
cls
echo ============
echo Starflight
echo ============
echo,
echo 1. Resume the game
echo ---
echo 4. Save the current game state
echo 5. Restore a saved game
echo 6. Delete a saved game
echo ---
echo 9. Reset the game
echo ---
echo X. Exit
echo.
choice /c:14569x /n
if errorlevel 6 goto exit
if errorlevel 5 goto reset
if errorlevel 4 goto delsave
if errorlevel 3 goto ressave
if errorlevel 2 goto cursave
if errorlevel 1 goto resume
goto mainmenu
:resume
cd play
starflt.com
cd ..
goto mainmenu
:cursave
set savegame=
cls
echo.
echo SAVED GAMES:
echo.
dir .\saved*.*
echo.
echo Which save number do you want to use to store the current game state?
echo.
echo [1...9, or X to abort]
choice /c:123456789x /n
if errorlevel 10 goto mainmenu
if errorlevel 9 set savegame=9
if errorlevel 9 goto dosave
if errorlevel 8 set savegame=8
if errorlevel 8 goto dosave
if errorlevel 7 set savegame=7
if errorlevel 7 goto dosave
if errorlevel 6 set savegame=6
if errorlevel 6 goto dosave
if errorlevel 5 set savegame=5
if errorlevel 5 goto dosave
if errorlevel 4 set savegame=4
if errorlevel 4 goto dosave
if errorlevel 3 set savegame=3
if errorlevel 3 goto dosave
if errorlevel 2 set savegame=2
if errorlevel 2 goto dosave
if errorlevel 1 set savegame=1
if errorlevel 1 goto dosave
if x%savegame%==x goto mainmenu
goto cursave
:dosaveover
echo.
echo Save number %savegame% already exists.
echo.
echo Do you want to overwrite it?
echo.
echo [Y]es or [N]o
choice /c:yn /n
if errorlevel 2 goto cursave
if errorlevel 1 goto dosave2
goto dosaveover
:dosave
if exist .\saved%savegame%\starflt.com goto dosaveover
goto dosave2
:dosave2
echo.
if exist .\saved%savegame%\starflt.com del .\saved%savegame%\*.*
if not exist .\saved%savegame%\nul mkdir .\saved%savegame%
copy .\play\*.com .\saved%savegame%
echo.
echo Current game state saved to game number %savegame%.
echo.
pause
set savegame=
goto mainmenu
:ressave
set savegame=
cls
echo.
echo SAVED GAMES:
echo.
dir .\saved*.*
echo.
echo Which game do you want to restore?
echo.
echo [1...9, or X to abort]
choice /c:123456789x /n
if errorlevel 10 goto mainmenu
if errorlevel 9 set savegame=9
if errorlevel 9 goto dores
if errorlevel 8 set savegame=8
if errorlevel 8 goto dores
if errorlevel 7 set savegame=7
if errorlevel 7 goto dores
if errorlevel 6 set savegame=6
if errorlevel 6 goto dores
if errorlevel 5 set savegame=5
if errorlevel 5 goto dores
if errorlevel 4 set savegame=4
if errorlevel 4 goto dores
if errorlevel 3 set savegame=3
if errorlevel 3 goto dores
if errorlevel 2 set savegame=2
if errorlevel 2 goto dores
if errorlevel 1 set savegame=1
if errorlevel 1 goto dores
if x%savegame%==x goto mainmenu
:dores
if not exist .\saved%savegame%\starflt.com goto resnosave
echo.
echo Are you sure you want to restore saved game number %savegame%?
echo (the current game state will be overwritten if you do)
echo.
echo [Y]es or [N]o
choice /c:yn /n
if errorlevel 2 goto ressave
if errorlevel 1 goto dores2
goto ressave
:dores2
echo.
copy .\saved%savegame%\*.* .\play
echo.
echo Save game number %savegame% restored.
echo.
pause
set savegame=
goto mainmenu
:resnosave
echo.
echo Save number %savegame% does not exist.
echo.
pause
goto ressave
:delsave
set savegame=
cls
echo.
echo SAVED GAMES:
echo.
dir .\saved*.*
echo.
echo Which game do you want to delete?
echo.
echo [1...9, or X to abort]
choice /c:123456789x /n
if errorlevel 10 goto mainmenu
if errorlevel 9 set savegame=9
if errorlevel 9 goto dodel
if errorlevel 8 set savegame=8
if errorlevel 8 goto dodel
if errorlevel 7 set savegame=7
if errorlevel 7 goto dodel
if errorlevel 6 set savegame=6
if errorlevel 6 goto dodel
if errorlevel 5 set savegame=5
if errorlevel 5 goto dodel
if errorlevel 4 set savegame=4
if errorlevel 4 goto dodel
if errorlevel 3 set savegame=3
if errorlevel 3 goto dodel
if errorlevel 2 set savegame=2
if errorlevel 2 goto dodel
if errorlevel 1 set savegame=1
if errorlevel 1 goto dodel
if x%savegame%==x goto mainmenu
:dodel
if not exist .\saved%savegame%\starflt.com goto delnosave
echo.
echo Are you sure you want to delete saved game number %savegame%?
echo.
echo [Y]es or [N]o
choice /c:yn /n
if errorlevel 2 goto delsave
if errorlevel 1 goto dodel2
goto delsave
:dodel2
echo.
del .\saved%savegame%\*.*
rmdir .\saved%savegame%
echo.
echo Save game number %savegame% deleted.
echo.
pause
set savegame=
goto mainmenu
:delnosave
echo.
echo Save number %savegame% does not exist
echo.
pause
goto delsave
:reset
cls
echo.
echo Are you sure you want to reset the game?
echo *ANY PROGRESS THAT HAS NOT BEEN BACKED UP WILL BE LOST*
echo (previously saved games will remain)
echo.
echo [Y]es or [N]o
choice /c:ny /n
if errorlevel 2 goto doreset
if errorlevel 1 goto mainmenu
goto mainmenu
:doreset
echo.
copy .\START\*.* .\PLAY
echo.
echo Game reset.
echo.
pause
goto mainmenu
:exit
cls
echo.
echo Are you sure you want to exit?
echo.
echo [Y]es or [N]o
choice /c:ny /n
if errorlevel 2 goto end
if errorlevel 1 goto mainmenu
goto exit
:end
@echo on

[/spoiler]

If anyone has any ideas to improve it; within the limitations of DOSBox commands, without adding any other files, they're welcome.

Bumped for greater justice.

I solved this problem in two ways, one simple and one pretty advanced.

Option 1: Install your game(s) in a Dropbox folder. Assuming you've got a stable internet connection this will provide versioning for the important files and you can restore previous versions from their web interface. Just make sure you restore STARA.COM and STARB.com from the same time.

Option 2 (Advanced): Use a distributed version control system such as git or mercurial, and commit your saves after each session. In this manner you can actually describe your save file progress in the commit message as a reference for reverting to a specific point in your story. My personal solution is extremely complex (involves a cygwin launcher script w/ ruby and git installed) but I'm sure it's possible to put together something more windows shell friendly.

O_O

And I thought I was crazy for writing a batch file for the first time in 10 years... :-D

Nice work, Links. I just finished adapting it to Wizardry 6 and am modifying it to work with Wizardry 7 and Wiz 7 Gold. I'll upload them to the Wizardry forum as soon as I finish testing them. =)

Of course, you'll get credit since you wrote this in the first place.

Flynn

Thanks. Just glad it was helpful for someone else.

I should thank you as well. I tried using the .bat from starflt.com and, due to my own ineptitude, could not get it to work with the GOG release. Thankfully, I found yours. Thank you and +1. :D

Besides the excellent other solutions in this thread, here is a simple .bat file collection that works in XP without the need for parameters or other input. Copy them into your PLAY directory and link to them from your desktop.

There are 3 .bat files:
STACK.BAT copies your in-game SAVE onto a stack of SAVEn directories (7 deep). Run it after every in-game SAVE.
RESTORE.BAT copies the most recent SAVE back into the PLAY directory. Run it if you die.
UNSTACK.BAT copies the entire stack back one level, losing the most recent SAVE. Use it if RESTORE.BAT doesn't take you far enough back.

echo on
REM STACK.BAT
REM
REM STACK.BAT is a Windows XP BAT file to save the current play state of
REM StarFlight by stacking it into the series of subdirectories SAVE...Save7.
REM
REM StarFlight keeps its SAVE state in its .COM files in its PLAY directory.
REM Keep this .BAT file in the PLAY directory, and keep a link to it on your
REM desktop.
REM
REM Get into the habit of running this BAT file each time you quit (and save) the game.
REM
REM To restore the next older SAVE, run UNSTACK.BAT
REM
mkdir ..\SAVE7
mkdir ..\SAVE6
mkdir ..\SAVE5
mkdir ..\SAVE4
mkdir ..\SAVE3
mkdir ..\SAVE2
mkdir ..\SAVE1
copy ..\SAVE6\*.com ..\SAVE7
copy ..\SAVE5\*.com ..\SAVE6
copy ..\SAVE4\*.com ..\SAVE5
copy ..\SAVE3\*.com ..\SAVE4
copy ..\SAVE2\*.com ..\SAVE3
copy ..\SAVE1\*.com ..\SAVE2
copy ..\SAVE\*.com ..\SAVE1
COPY *.COM ..\SAVE
PAUSE
:finished


echo on
REM You are about to lose your current game and restore from the most
REM recent SAVE. If you don't want to do that, press Ctrl-C now to abort.
PAUSE
REM
REM RESTORE.BAT
REM
REM RESTORE.BAT is a Windows XP BAT file to restore the next older play state of
REM StarFlight by copying it from the subdirectory SAVE.
REM
REM StarFlight keeps its SAVE state in its .COM files in its PLAY directory.
REM Keep this .BAT file in the PLAY directory, and keep a link to it on your
REM desktop.
REM
REM Get into the habit of running STACK.BAT each time you quit (and save) the game.
REM
REM To restore the next older SAVE, run UNSTACK.BAT
REM
COPY ..\SAVE\*.COM .
PAUSE
:finished


echo on
REM You are about to lose your current game and restore from the most
REM recent SAVE. If you don't want to do that, press Ctrl-C now to abort.
PAUSE
REM
REM UNSTACK.BAT
REM
REM UNSTACK.BAT is a Windows XP BAT file to restore the next older play state of
REM StarFlight by unstacking it from the series of subdirectories SAVE...Save7.
REM
REM StarFlight keeps its SAVE state in its .COM files in its PLAY directory.
REM Keep this .BAT file in the PLAY directory, and keep a link to it on your
REM desktop.
REM
REM Get into the habit of running STACK.BAT each time you quit (and save) the game.
REM
REM To restore the next older SAVE, run UNSTACK.BAT
REM
REM Note: You will lose one SAVE each time you run this script.
REM That keeps things simple.
REM
COPY ..\SAVE\*.COM .
copy ..\SAVE1\*.com ..\SAVE
copy ..\SAVE2\*.com ..\SAVE1
copy ..\SAVE3\*.com ..\SAVE2
copy ..\SAVE4\*.com ..\SAVE3
copy ..\SAVE5\*.com ..\SAVE4
copy ..\SAVE6\*.com ..\SAVE5
copy ..\SAVE7\*.com ..\SAVE6
PAUSE
:finished


That link no longer works.

Is there a way to do this in window 8? I can't locate a STARA or STARB file. thanks


Ok found the directory in windows 8 and the STARA and STARB file; But when copy and try to open you get a need app to open contact original program. If you copy the whole GOG directory to a CD you can install the game from that, but if you die it will not reinstall from when you copied. You get Game in progress not saved even if you load from the original CD. Since I am an old fart and not computer savvy writing bathc files etc. is not an option.

Thanks for any help available.